IchigoJam(8) <8x8LED>

IchigoJamだけでダイナミック表示ができたので8x8マトリクスLEDを点けてみた。

　IchigoJamの出力ポートはOUT1～OUT11の11本しかないので、OUT1～OUT8をマトリクスLEDのR1～R8に接続して、カラム側は74HC138(3-8Decoder)を使ってOUT9～OUT11でC1～C8をドライブする。R1～R8は0Ωに(直結)した。LEDが点灯する数によって明るさが違う。

　C1～C7を駆動する74HC138の出力は負論理なので、例えば入力が"101"ならば出力Y4に"L"が出力される。したがってR1～R7は正論理で駆動すればよい。

　例えば、2列目に「○●○●●○●○」(C1→C8、○ON、●OFF)のパターンを表示する場合、OUT #2A5 とする。

　とりあえずテストプログラムを書いてみた。4つのパターンで点灯する。

1. 順に点灯
2. 渦巻き
3. ランダム
4. 反射

1 '8x8LED TEST
10 GOSUB 1000
20 GOSUB 100: GOSUB 200: GOSUB 300: GOSUB 400
30 FOR Z=0 TO 4
40  R=RND(4): R=(R+1)*100: GOSUB R
50 NEXT
90 END

100 'ALL LED ZigZag
100 FOR Y=0 TO 7 
110  IF Y%2=0 T=0: E=7: S=1 ELSE T=7: E=0: S=-1
120  FOR X=T TO E STEP S
130   GOSUB 900
140  NEXT
150 NEXT
160 RETURN

200 'Spilal
200 X=0:
210 FOR A=0 TO 3: B=7-A
220  FOR Y=A TO B: GOSUB 900: NEXT
230  FOR X=X+1 TO B : GOSUB 900: NEXT
240  FOR Y=Y-1 TO A STEP -1: GOSUB 900: NEXT
250  IF A<3 FOR X=X-1 TO A+1 STEP -1: GOSUB 900: NEXT 
260 NEXT  
270 RETURN

300 'Random
300 FOR P=0 TO 63
310  R=RND(63): Y=R/8: X=R%8: GOSUB 900
320 NEXT 
330 RETURN

400 'Reflect 
400 A=1: B=2: X=3: Y=4
410 FOR P=0 TO 63
420  GOSUB 900
430  X=X+A: Y=Y+B
440  IF X<0 X=0: A=RND(2): A=A+1: GOTO 460
450  IF 7<X X=7: A=-A
460  IF Y<0 Y=0: B=RND(2): B=B+1: GOTO 480
470  IF 7<Y Y=7: B=-B 
480 NEXT
490 RETURN

900 'LED(X,Y) ON
900 OUT (X<<8)|(1<<Y): WAIT 5: RETURN

1000 'Initialize
1000 FOR I=8 TO 11: OUT I,0: NEXT
1100 RETURN
LIST

↑リンク先に Ichigo8x8LEDtest.avi (999.2K)

↑はLEDの同時点灯数1個だから簡単だ。結構簡単にできたので 気をよくして、パターンを表示させてみた。

1 '8x8LED display
2 'NOV. 2015/ Yoshi
10 GOSUB 1000: GOSUB 1200

100 'Main loop
100 I=I+1: J=(I&7): D=(I&T)>>5: OUT (J<<8)|[D+J]: IF I&#1FF=0 GOSUB 500
110 GOTO 100

500 'button
500 IF BTN()=0 B=0: RETURN 
510 'ELSE 
510  P=P+1: IF P=2 P=0
520  IF P=0 T=#3E0: GOTO 540
530  IF P=1 T=#700: GOTO 540
540  IF B=0 B=1: BEEP: ELSE END
550 RETURN

1000 'Initialize
1000 CLV: VIDEO 0
1010 V=60: N=V: P=1: S=0: T=#700
1020 OUT 8,0: OUT 9,0: OUT 10,0: OUT 11,0
1030 CLT
1100 RETURN

1200 'Bit pattern 
1200 LET [0],#00,#03,#0F,#1C,#F8,#F0,#0C,#03
1210 LET [8],#00,#3C,#7E,#FF,#81,#C3,#7E,#3C
1220 LET [16],#00,#46,#8F,#9F,#B9,#F9,#F1,#62
1230 LET [24],#00,#FF,#FF,#FF,#18,#18,#FF,#FF
1240 LET [32],#00,#00,#81,#FF,#FF,#FF,#81,#00
1250 LET [40],#00,#88,#58,#7C,#3F,#7C,#58,#88
1300 RETURN
LIST

1200行から1250行までが表示パターン。

例えば、1200行は、配列[0]～[7]に"Y"のパターンを格納している。

[0][1][2][3][4][5][6][7]
・ ○ ○ ・ ・ ・ ・ ○ 01h
・ ○ ○ ・ ・ ・ ・ ○ 02h
・ ・ ○ ○ ・ ・ ○ ・ 04h
・ ・ ○ ○ ○ ・ ○ ・ 08h
・ ・ ・ ○ ○ ○ ・ ・ 10h
・ ・ ・ ・ ○ ○ ・ ・ 20h
・ ・ ・ ・ ○ ○ ・ ・ 30h
・ ・ ・ ・ ○ ○ ・ ・ 40h
00 03 0F 1C F8 F0 0C 03

のように格納してある。

　メインループ（100行110行)を、どれだけ速く書くかでチラつきかたが変わってくる。（もう少し速くなるかも）　効果があるのは行数を減らすことだった。

↑リンク先に Ichigo8x8LEDdisp.avi (900.5K)

　さすがにチラつくなあ。ビデオではわからないけどLEDの点灯数で明るさが違うのが、はっきり分かる。

メインループを早くするアイディア

• 74HC138(3-8Decoder)でなく74HC4017(JohnsonCounter)を使う
• 配列アクセスをPOKEに変える

くらいかなあ。

　タイマー割り込みが欲しい。

---

• IchigoJam(2015/03/30)
• IchigoJam BASICのFOR/NEXT(2015/04/05)
• IchigoJam BASICのFOR/NEXT(2)(2015/04/07)
• IchigoJam(2) -IchigoJamそっくりさんを作る-(2015/05/17)
• IchigoJam(3) -超小型ARMマイコン基板- (2015/05/)
• IchigoJam(4) -モリダンプ・プログラム-(2015/06/01)
• IchigoJam(5) -HDSP0670を使った4digit clock-(2015/09/24)
• IchigoJam(6) <4桁時計ダイナミック表示>（2015/10/13）
• IchigoJam(7) <OUT8～OUT11使用 4桁時計ダイナミック表示>(2015/10/19)
• IchigoJam,(8) <8x8LED>
• IchigoJam(9) <8x8LEDで8Qeen問題>(2015/11/10)
• IchigoJam(10) <8x8LEDを光センサーにする>(2015/11/17)
• IchigoJam(10) <LED&KEY>(2018/04/08)
• IchigoJam(11) <LED&KEYを機械語で>(2018/04/15)

---

【最近の投稿】【最近のCPUボード】【最近のIchigoJam】【2017の投稿】【2016の投稿】【2015の投稿】